{
  inputs.nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
  inputs.systems.url = "github:nix-systems/default-linux";

  outputs =
    {
      self,
      nixpkgs,
      systems,
    }:
    let
      forAllSystems =
        func: nixpkgs.lib.genAttrs (import systems) (system: func (import nixpkgs { inherit system; }));
    in
    {
      devShells = forAllSystems (pkgs: {
        default = pkgs.mkShell {
          packages = with pkgs; [
            cargo
            rustc
            rust-analyzer
            rustfmt
            clippy
          ];
        };
      });
      packages = forAllSystems (pkgs: {
        default = self.packages.${pkgs.system}.yoke;
        yoke = pkgs.rustPlatform.callPackage ./nix/package.nix {
          features = [
            "cli"
          ];
        };
        yoke-lite = pkgs.rustPlatform.callPackage ./nix/package.nix { };
      });
      nixosModules.default =
        { pkgs, ... }:
        {
          imports = [ ./nix/module.nix ];
          programs.yoke.package = self.packages.${pkgs.system}.yoke;
        };
    };
}