{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
    nix-systems.url = "github:nix-systems/default-linux";
  };

  outputs =
    inputs:
    with inputs;
    let
      forAllSystems =
        function:
        nixpkgs.lib.genAttrs (import nix-systems) (system: function nixpkgs.legacyPackages.${system});
    in
    {
      packages = forAllSystems (pkgs: {
        default = pkgs.writeShellApplication {
          name = "smooooth";
          runtimeInputs = builtins.attrValues {
            inherit (pkgs)
              polkit
              gnugrep
              coreutils
              libnotify
              inotify-tools
              nix
              ;
          };
          text = builtins.readFile ./smooooth.sh;
        };
      });
      nixosModules.smooooth =
        {
          config,
          options,
          pkgs,
          lib,
          ...
        }:
        {
          imports = [ ./module.nix ];
          services.smooooth.package = self.packages.${pkgs.system}.default;
        };
    };
}