{inputs, ...}: {
  additions = final: _prev: import ./pkgs {pkgs = final;};
  pkg-sets = final: prev: {
    unstable = import inputs.nixpkgs {
      system = final.system;
      config.allowUnfree = true;
    };
    stable = import inputs.nixpkgs-stable {
      system = final.system;
      config.allowUnfree = true;
    };
  };
  rice = import ./rice.nix;
  podman-stable = final: prev: {podman-stable = final.stable.podman;};
  wlroots = final: prev: {
    wlroots = final.unstable.wlroots_0_16.overrideAttrs (wfinal: wprev: {
      postPatch =
        wprev.postPatch
        + ''
          substituteInPlace render/gles2/renderer.c --replace "glFlush();" "glFinish();"
        '';
    });
  };
  sway-unwrapped = final: prev: {
    sway-unwrapped =
      (final.unstable.sway-unwrapped.override {
        wlroots = final.wlroots;
        systemdSupport = true;
        trayEnabled = true;
      })
      .overrideAttrs (
        sfinal: sprev: {
          patches = (sprev.patches or []) ++ [./sway-nvidia.patch];
        }
      );
  };
  sway = final: prev: {
    sway = final.unstable.sway.override {
      sway-unwrapped = final.sway-unwrapped;
      withBaseWrapper = true;
      withGtkWrapper = true;
    };
  };
  swayfx = final: prev: {swayfx = final.unstable.swayfx.override {sway-unwrapped = final.sway-unwrapped;};};
}