{
  lib,
  pkgs,
  inputs,
  getFlakePkg,
  ...
}:
let
  extensions = {
    adnauseam = {
      id = "dlkmkipjfgcmnfckfdflcemkhlfbeiak";
      updateUrl = "https://gist.githubusercontent.com/amaanq/791db15b547cf00d27c99e784bbe0459/raw/adnauseam-updates.xml";
    };
    bypass-paywalls = {
      id = "lkbebcjgcmobigpeffafkodonchffocl";
      updateUrl = "https://gitflic.ru/project/magnolia1234/bpc_updates/blob/raw?file=updates.xml";
    };
    vencord = {
      id = "jfcaohdhgnfchhifdffmldmodkmndfjp";
      updateUrl = "https://github.com/amaanq/Vencord/releases/latest/download/updates.xml";
    };
    bitwarden.id = "nngceckbapebfimnlniiiahkandclblb";
    clearurls.id = "lckanjgmijmafbedllaakclkaicjfmnk";
    dark-reader.id = "eimadpbcbfnmbkopoojfekhnkhdbieeh";
    i-still-dont-care-about-cookies.id = "edibdbjcniadpccecjdfdjjppcpchdlm";
    fastforward.id = "icallnadddjmdinamnolclfjanhfoafe";
    refined-github.id = "hlepfoohegkhhmjieoechaddaejaokhf";
    sponsorblock.id = "mnjggcdmjocbbbhaepdhchncahnbgone";
    vimium-c.id = "hfjbmagddngcpeloejdejnfgbamkjaeg";
    web-archives.id = "hkligngkgcpcolhcnkgccglchdafcnao";
    # webrtc-leak-shield.id = "bppamachkoflopbagkdoflbgfjflfnfl";
  };
  extensionStrings = map (
    key:
    let
      ext = extensions.${key};
      url = ext.updateUrl or "https://services.helium.imput.net/ext";
    in
    "${ext.id};${url}"
  ) (builtins.attrNames extensions);
in
(scope "apps.browser" <| getFlakePkg inputs.helium)
// scope "programs.chromium" {
  enable = true;
  extensions = extensionStrings;
  extraOpts = {
    PrivacySandboxFingerprintingProtectionEnabled = true;
    PrivacySandboxIpProtectionEnabled = true;
    # Explicitly allow our extensions
    ExtensionInstallAllowlist = map (entry: entry.value.id) (lib.attrsToList extensions);
    # Allow extensions from Helium proxy and self-hosted sources
    ExtensionInstallSources = [
      "https://services.helium.imput.net/*" # Helium proxy
      "https://rednoise.org/*" # AdNauseam manifest
      "https://github.com/*" # AdNauseam CRX host
      "https://*.githubusercontent.com/*" # GitHub release assets
      "https://gitflic.ru/*" # Bypass Paywalls
    ];
  };
}