{
  config,
  scope,
  machineName,
  mainUser,
  ...
}:
scope "boot" {
  tmp.useTmpfs = true;
  initrd.systemd.enable = true;

  loader.limine = {
    enable = true;
    style =
      let
        pal = config.rice.palette.shortHex;
      in
      {
        wallpapers = [ config.rice.bg.src ];
        interface = {
          brandingColor = 1;
          branding = "hello ${mainUser}. welcome to ${machineName}";
        };
        graphicalTerminal =
          let
            getPal = p: builtins.attrValues p |> builtins.concatStringsSep ";";
          in
          {
            palette = getPal pal.normal;
            brightPalette = getPal pal.bright;
            marginGradient = 0;
            margin = 256;
            foreground = pal.util.fg;
            background = "20" + pal.util.bg;
            brightForeground = pal.bright.yellow;
            brightBackground = pal.util.bg;
          };
        backdrop = pal.util.bg;
      };
    maxGenerations = 5;
  };
  plymouth = {
    enable = true;
    # theme needs fixing
    # inherit (config.rice.plymouth) theme themePackages font;
  };

  loader.limine.extraEntries = ''
    /Windows
      protocol: efi
      path: boot():/EFI/Microsoft/Boot/bootmgfw.efi
  '';
}