{
  pkgs,
  config,
  ...
}:
let
  inherit (config) rice;
  pal = rice.palette.hex;
in
{
  hm.programs.wlogout = {
    enable = true;
    package = pkgs.wleave;
    layout = builtins.fromJSON (builtins.readFile ./logout/layout);
    style =
      with pal;
      (builtins.replaceStrings
        [
          "/usr/share/wlogout"
          "/etc/wlogout"
          "#WINBG"
          "#BTNCOL"
          "#BTNBG"
          "#BTNFOCUSBG"
          "#WINLOGO"
        ]
        [
          "${pkgs.wlogout}/share/wlogout"
          "${pkgs.wlogout}/etc/wlogout"
          util.bg
          bright.yellow
          util.bg
          normal.black
          (builtins.path {
            name = "winlogo";
            path = ../assets/winlogo.png;
            sha256 = "7c1ff96b553c7a7ca3a7b7cf8efe830ab7feea92355aed288a10ee7347c24108";
          })
        ]
        (builtins.readFile ./logout/style.css)
      );
  };

  hm.home.packages = [ pkgs.wleave ];
}
