{
  description = "User-defined short URL schemes for Nix flake references";

  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

  outputs =
    { self, nixpkgs }:
    let
      forAllSystems = nixpkgs.lib.genAttrs [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];
    in
    {
      nixosModules.default =
        { pkgs, ... }:
        {
          imports = [ ./module.nix ];
          nix.shorturls.package = self.packages.${pkgs.stdenv.hostPlatform.system}.default;
        };

      packages = forAllSystems (
        system:
        let
          pkgs = nixpkgs.legacyPackages.${system};
        in
        {
          default = pkgs.stdenv.mkDerivation {
            pname = "nix-shorturl-plugin";
            version = "0.1.0";
            src = self;

            nativeBuildInputs = with pkgs; [
              meson
              ninja
              pkg-config
            ];

            buildInputs = with pkgs; [
              nix.dev
              nlohmann_json
              boost
            ];
          };
        }
      );

      devShells = forAllSystems (
        system:
        let
          pkgs = nixpkgs.legacyPackages.${system};
        in
        {
          default = pkgs.mkShell {
            packages = with pkgs; [
              meson
              ninja
              pkg-config
              nix.dev
              nlohmann_json
              boost
              clang-tools
            ];
          };
        }
      );
    };
}