{
  description = "Airdrome — modern web UI for Subsonic-compatible music servers";

  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

  outputs =
    { self, nixpkgs }:
    let
      supportedSystems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];
      forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
    in
    {
      packages = forAllSystems (
        system:
        let
          pkgs = nixpkgs.legacyPackages.${system};
          airdrome = pkgs.callPackage ./package.nix { };
        in
        {
          inherit airdrome;
          default = airdrome;
        }
      );

      overlays.default = final: prev: {
        airdrome = final.callPackage ./package.nix { };
      };

      nixosModules.default = self.nixosModules.airdrome;
      nixosModules.airdrome =
        { pkgs, ... }:
        {
          imports = [ ./module.nix ];
          services.airdrome.package = self.packages.${pkgs.stdenv.hostPlatform.system}.airdrome;
        };
    };
}